D Programming Language 2.0

Last update Wed Apr 11 21:24:35 2012


This module implements a variety of type constructors, i.e., templates that allow construction of new, useful general-purpose types.


// value tuples
alias Tuple!(float, "x", float, "y", float, "z") Coord;
Coord c;
c[1] = 1;       // access by index
c.z = 1;        // access by given name
alias Tuple!(string, string) DicEntry; // names can be omitted

// Rebindable references to const and immutable objects
void bar()
    const w1 = new Widget, w2 = new Widget;
    // w1 = w2 would not work; can't rebind const object
    auto r = Rebindable!(const Widget)(w1);
    // invoke method as if r were a Widget object
    // rebind r to refer to another object
    r = w2;

Boost License 1.0.

Andrei Alexandrescu, Bartosz Milewski, Don Clugston, Shin Fujishiro

struct Unique(T);
Encapsulates unique ownership of a resource. Resource of type T is deleted at the end of the scope, unless it is transferred. The transfer can be explicit, by calling release, or implicit, when returning Unique from a function. The resource can be a polymorphic class object, in which case Unique behaves polymorphically too.


this(RefT p);
Constructor that takes an rvalue. It will ensure uniqueness, as long as the rvalue isn't just a view on an lvalue (e.g., a cast) Typical usage:
    Unique!(Foo) f = new Foo;

this(ref RefT p);
Constructor that takes an lvalue. It nulls its source. The nulling will ensure uniqueness as long as there are no previous aliases to the source.

Unique release();
Returns a unique rvalue. Nullifies the current contents

RefT opDot();
Forwards member access to contents

struct Tuple(Specs...);
Tuple of values, for example Tuple!(int, string) is a record that stores an int and a string. Tuple can be used to bundle values together, notably when returning multiple values from a function. If obj is a tuple, the individual members are accessible with the syntax obj[0] for the first field, obj[1] for the second, and so on.

The choice of zero-based indexing instead of one-base indexing was motivated by the ability to use value tuples with various compile-time loop constructs (e.g. type tuple iteration), all of which use zero-based indexing.

Tuple!(int, int) point;
// assign coordinates
point[0] = 5;
point[1] = 6;
// read coordinates
auto x = point[0];
auto y = point[1];
Tuple members can be named. It is legal to mix named and unnamed members. The method above is still applicable to all fields.

alias Tuple!(int, "index", string, "value") Entry;
Entry e;
e.index = 4;
e.value = "Hello";
assert(e[1] == "Hello");
assert(e[0] == 4);
Tuples with named fields are distinct types from tuples with unnamed fields, i.e. each naming imparts a separate type for the tuple. Two tuple differing in naming only are still distinct, even though they might have the same structure.

Tuple!(int, "x", int, "y") point1;
Tuple!(int, int) point2;
assert(!is(typeof(point1) == typeof(point2))); // passes

alias Types;
The type of the tuple's components.

this(U...)(U values);
Constructor taking one value for each field. Each argument must be implicitly assignable to the respective element of the target.

this(U)(U another);
Constructor taking a compatible tuple. Each element of the source must be implicitly assignable to the respective element of the target.

bool opEquals(R)(R rhs);
Comparison for equality.

int opCmp(R)(R rhs);
Comparison for ordering.

void opAssign(R)(R rhs);
Assignment from another tuple. Each element of the source must be implicitly assignable to the respective element of the target.

Tuple!(sliceSpecs!(from,to)) slice(uint from, uint to)();
Takes a slice of the tuple.

Tuple!(int, string, float, double) a;
a[1] = "abc";
a[2] = 4.5;
auto s = a.slice!(1, 3);
static assert(is(typeof(s) == Tuple!(string, float)));
assert(s[0] == "abc" && s[1] == 4.5);

string toString();
Converts to string.

Tuple!(T) tuple(T...)(T args);
Returns a Tuple object instantiated and initialized according to the arguments.

auto value = tuple(5, 6.7, "hello");
assert(value[0] == 5);
assert(value[1] == 6.7);
assert(value[2] == "hello");

template isTuple(T)
Returns true if and only if T is an instance of the Tuple struct template.

template defineEnum(string name,T...)
Defines truly named enumerated values with parsing and stringizing primitives.

mixin(defineEnum!("Abc", "A", "B", 5, "C"));
is equivalent to the following code:

enum Abc { A, B = 5, C }
string enumToString(Abc v) { ... }
Abc enumFromString(string s) { ... }
The enumToString function generates the unqualified names of the enumerated values, i.e. "A", "B", and "C". The enumFromString function expects one of "A", "B", and "C", and throws an exception in any other case.

A base type can be specified for the enumeration like this:

mixin(defineEnum!("Abc", ubyte, "A", "B", "C", 255));
In this case the generated enum will have a ubyte representation.

template Rebindable(T) if (is(T == class) || is(T == interface) || isArray!(T))
Rebindable!(T) is a simple, efficient wrapper that behaves just like an object of type T, except that you can reassign it to refer to another object. For completeness, Rebindable!(T) aliases itself away to T if T is a non-const object type. However, Rebindable!(T) does not compile if T is a non-class type.

Regular const object references cannot be reassigned:

class Widget { int x; int y() const { return a; } }
const a = new Widget;
a.y();          // fine
a.x = 5;        // error! can't modify const a
a = new Widget; // error! can't modify const a
However, Rebindable!(Widget) does allow reassignment, while otherwise behaving exactly like a const Widget:

auto a = Rebindable!(const Widget)(new Widget);
a.y();          // fine
a.x = 5;        // error! can't modify const a
a = new Widget; // fine
You may want to use Rebindable when you want to have mutable storage referring to const objects, for example an array of references that must be sorted in place. Rebindable does not break the soundness of D's type system and does not incur any of the risks usually associated with cast.

Rebindable!(T) rebindable(T)(T obj);
Convenience function for creating a Rebindable using automatic type inference.

Rebindable!(T) rebindable(T)(Rebindable!(T) obj);
This function simply returns the Rebindable object passed in. It's useful in generic programming cases when a given object may be either a regular class or a Rebindable.

string alignForSize(E...)(string[] names...);
Order the provided members to minimize size while preserving alignment. Returns a declaration to be mixed in.

struct Banner {
  mixin(alignForSize!(byte[6], double)(["name", "height"]));
Alignment is not always optimal for 80-bit reals, nor for structs declared as align(1).

struct Nullable(T);
Defines a value paired with a distinctive "null" state that denotes the absence of a value. If default constructed, a Nullable!T object starts in the null state. Assigning it renders it non-null. Calling nullify can nullify it again.

Nullable!int a;
a = 5;
assert(a == 5);
Practically Nullable!T stores a T and a bool.

this()(T value);
Constructor initializing this with value.

const pure nothrow @safe bool isNull();
Returns true if and only if this is in the null state.

void nullify()();
Forces this to the null state.

void opAssign()(T value);
Assigns value to the internally-held state. If the assignment succeeds, this becomes non-null.

inout pure @safe inout(T) get();
Gets the value. Throws an exception if this is in the null state. This function is also called for the implicit conversion to T.

struct Nullable(T,T nullValue);
Just like Nullable!T, except that the null state is defined as a particular value. For example, Nullable!(uint, uint.max) is an uint that sets aside the value uint.max to denote a null state. Nullable!(T, nullValue) is more storage-efficient than Nullable!T because it does not need to store an extra bool.

this()(T value);
Constructor initializing this with value.

const bool isNull()();
Returns true if and only if this is in the null state.

void nullify()();
Forces this to the null state.

void opAssign()(T value);
Assigns value to the internally-held state. No null checks are made.

inout inout(T) get()();
Gets the value. Throws an exception if this is in the null state. This function is also called for the implicit conversion to T.

struct NullableRef(T);
Just like Nullable!T, except that the object refers to a value sitting elsewhere in memory. This makes assignments overwrite the initially assigned value. Internally NullableRef!T only stores a pointer to T (i.e., Nullable!T.sizeof == (T*).sizeof).

pure nothrow @safe this(T* value);
Constructor binding this with value.

pure nothrow @safe void bind(T* value);
Binds the internal state to value.

const pure nothrow @safe bool isNull();
Returns true if and only if this is in the null state.

pure nothrow @safe void nullify();
Forces this to the null state.

void opAssign()(T value);
Assigns value to the internally-held state.

inout inout(T) get()();
Gets the value. Throws an exception if this is in the null state. This function is also called for the implicit conversion to T.

template BlackHole(Base)
BlackHole!Base is a subclass of Base which automatically implements all abstract member functions in Base as do-nothing functions. Each auto-implemented function just returns the default value of the return type without doing anything.

The name came from Class::BlackHole Perl module by Sean M. Burke.

abstract class C
    int m_value;
    this(int v) { m_value = v; }
    int value() @property { return m_value; }

    abstract real realValue() @property;
    abstract void doSomething();

void main()
    auto c = new BlackHole!C(42);
    writeln(c.value);     // prints "42"

    // Abstract functions are implemented as do-nothing:
    writeln(c.realValue); // prints "NaN"
    c.doSomething();      // does nothing

See Also:
AutoImplement, generateEmptyFunction

template WhiteHole(Base)
WhiteHole!Base is a subclass of Base which automatically implements all abstract member functions as throw-always functions. Each auto-implemented function fails with throwing an Error and does never return. Useful for trapping use of not-yet-implemented functions.

The name came from Class::WhiteHole Perl module by Michael G Schwern.

class C
    abstract void notYetImplemented();

void main()
    auto c = new WhiteHole!C;
    c.notYetImplemented(); // throws an Error

Nothrow functions cause program to abort in release mode because the trap is implemented with assert(0) for nothrow functions.

See Also:
AutoImplement, generateAssertTrap

class AutoImplement(Base,alias how,alias what = isAbstractFunction): Base;
AutoImplement automatically implements (by default) all abstract member functions in the class or interface Base in specified way.

how template which specifies how functions will be implemented/overridden.

Two arguments are passed to how: the type Base and an alias to an implemented function. Then how must return an implemented function body as a string.

The generated function body can use these keywords:
  • a0, a1, …: arguments passed to the function;
  • args: a tuple of the arguments;
  • self: an alias to the function itself;
  • parent: an alias to the overridden function (if any).

You may want to use templated property functions (instead of Implicit Template Properties) to generate complex functions:
// Prints log messages for each call to overridden functions.
string generateLogger(C, alias fun)() @property
    enum qname = C.stringof ~ "." ~ __traits(identifier, fun);
    string stmt;

    stmt ~= q{ struct Importer { import std.stdio; } };
    stmt ~= `Importer.writeln("Log: ` ~ qname ~ `(", args, ")");`;
    static if (!__traits(isAbstractFunction, fun))
        static if (is(typeof(return) == void))
            stmt ~= q{ parent(args); };
            stmt ~= q{
                auto r = parent(args);
                Importer.writeln("--> ", r);
                return r;
    return stmt;
what template which determines what functions should be implemented/overridden.

An argument is passed to what: an alias to a non-final member function in Base. Then what must return a boolean value. Return true to indicate that the passed function should be implemented/overridden.

// Sees if fun returns something.
template hasValue(alias fun)
    enum bool hasValue = !is(ReturnType!(fun) == void);

Generated code is inserted in the scope of std.typecons module. Thus, any useful functions outside std.typecons cannot be used in the generated code. To workaround this problem, you may import necessary things in a local struct, as done in the generateLogger() template in the above example.

  • Variadic arguments to constructors are not forwarded to super.
  • Deep interface inheritance causes compile error with messages like "Error: function std.typecons.AutoImplement!(Foo).AutoImplement.bar does not override any function". [Bugzilla 2525, Bugzilla 3525]
  • The parent keyword is actually a delegate to the super class' corresponding member function. [Bugzilla 2540]
  • Using alias template parameter in how and/or what may cause strange compile error. Use template tuple parameter instead to workaround this problem. [Bugzilla 4217]

template generateEmptyFunction(C,func...)
template generateAssertTrap(C,func...)
Predefined how-policies for AutoImplement. These templates are used by BlackHole and WhiteHole, respectively.

enum RefCountedAutoInitialize;
Options regarding auto-initialization of a RefCounted object (see the definition of RefCounted below).

Do not auto-initialize the object

Auto-initialize the object

struct RefCounted(T,RefCountedAutoInitialize autoInit = RefCountedAutoInitialize.yes) if (!is(T == class));
Defines a reference-counted object containing a T value as payload. RefCounted keeps track of all references of an object, and when the reference count goes down to zero, frees the underlying store. RefCounted uses malloc and free for operation.

RefCounted is unsafe and should be used with care. No references to the payload should be escaped outside the RefCounted object.

The autoInit option makes the object ensure the store is automatically initialized. Leaving autoInit == RefCountedAutoInitialize.yes (the default option) is convenient but has the cost of a test whenever the payload is accessed. If autoInit == RefCountedAutoInitialize.no, user code must call either refCountedIsInitialized or refCountedEnsureInitialized before attempting to access the payload. Not doing so results in null pointer dereference.

// A pair of an int and a size_t - the latter being the
// reference count - will be dynamically allocated
auto rc1 = RefCounted!int(5);
assert(rc1 == 5);
// No more allocation, add just one extra reference count
auto rc2 = rc1;
// Reference semantics
rc2 = 42;
assert(rc1 == 42);
// the pair will be freed when rc1 and rc2 go out of scope

this(A...)(A args);
Constructor that initializes the payload.


void opAssign(typeof(this) rhs);
void opAssign(T rhs);
Assignment operators

T refCountedPayload();
Returns a reference to the payload. If (autoInit == RefCountedAutoInitialize.yes), calls refCountedEnsureInitialized. Otherwise, just issues assert(refCountedIsInitialized). Used with alias refCountedPayload this;, so callers can just use the RefCounted object as a T.

template Proxy(alias a)
Make proxy for a.

struct MyInt
    private int value;
    mixin Proxy!value;

    this(int n){ value = n; }

MyInt n = 10;

// Enable operations that original type has.
assert(n == 11);
assert(n * 2 == 22);

void func(int n) { }

// Disable implicit conversions to original type.
//int x = n;

template Typedef(T)
struct Typedef(T,T init,string cookie = null);
Library typedef.

Scoped!(T) scoped(T, Args...)(Args args);
Allocates a class object right inside the current scope, therefore avoiding the overhead of new. This facility is unsafe; it is the responsibility of the user to not escape a reference to the object outside the scope.

    class A { int x; }
    auto a1 = scoped!A();
    auto a2 = scoped!A();
    a1.x = 42;
    a2.x = 53;
    assert(a1.x == 42);

template Flag(string name)
Defines a simple, self-documenting yes/no flag. This makes it easy for APIs to define functions accepting flags without resorting to bool, which is opaque in calls, and without needing to define an enumerated type separately. Using Flag!"Name" instead of bool makes the flag's meaning visible in calls. Each yes/no flag has its own type, which makes confusions and mix-ups impossible.

// Before
string getLine(bool keepTerminator)
    if (keepTerminator) ...
// Code calling getLine (usually far away from its definition) can't
// be understood without looking at the documentation, even by users
// familiar with the API. Assuming the reverse meaning
// (i.e. "ignoreTerminator") and inserting the wrong code compiles and
// runs with erroneous results.
auto line = getLine(false);

// After
string getLine(Flag!"KeepTerminator" keepTerminator)
    if (keepTerminator) ...
// Code calling getLine can be easily read and understood even by
// people not fluent with the API.
auto line = getLine(Flag!"KeepTerminator".yes);
Passing categorical data by means of unstructured bool parameters is classified under "simple-data coupling" by Steve McConnell in the Code Complete book, along with three other kinds of coupling. The author argues citing several studies that coupling has a negative effect on code quality. Flag offers a simple structuring method for passing yes/no flags to APIs.

As a perk, the flag's name may be any string and as such can include characters not normally allowed in identifiers, such as spaces and dashes.

enum Flag;

When creating a value of type Flag!"Name", use Flag!"Name".no for the negative option. When using a value of type Flag!"Name", compare it against Flag!"Name".no or just false or 0.

When creating a value of type Flag!"Name", use Flag!"Name".yes for the affirmative option. When using a value of type Flag!"Name", compare it against Flag!"Name".yes.

struct Yes;
struct No">No;
Convenience names that allow using e.g. yes!"encryption" instead of Flag!"encryption".yes and no!"encryption" instead of Flag!"encryption".no.